怎样实现可扩展/收缩的对话框

类别:编程语言 点击:0 评论:0 推荐:
怎样实现可扩展/收缩的对话框

  在软件的界面设计上,简洁、高效永远是追求的目标。可扩展/收缩的对话框能有效的利用屏幕空间资源,展开后能提供较多的设置选项,收拢后又能节省屏幕空间资源,免除一些次要选项对操作的干扰。下面介绍实现原理和细节。图示分别为收拢后和展开后的界面,例子

  

原理

  设计对话框时是完整的(也就是展开后)大小,当对话框初始化时我们只显示一部分,也就是收拢后的效果。只显示一部分对话框界面的功能可以通过函数 SetWindowPos 来实现。下面是它的原型:

  BOOL SetWindowPos(
    HWND hWnd, // handle of window
    HWND hWndInsertAfter, // placement-order handle
    int X, // horizontal position
    int Y, // vertical position
    int cx, // width
    int cy, // height
    UINT uFlags // window-positioning flags
  );

cx 就是窗口重新设置的宽度。
cy 就是窗口重新设置的高度。

我们这样来调用它:

invoke SetWindowPos, hWnd, NULL, 0, 0, ebx, eax, SWP_NOZORDER or SWP_NOMOVE

其中 ebx 和 eax 就是新的窗口宽度和高度。

  初始化对话框大小后,在程序中我们还要能响应按钮消息展开/收拢对话框。所以我们把设置窗口大小的代码编写成一个函数,在需要的时候就可以调用。具体实现代码如下:

例子

.386
.model flat,stdcall
option casemap:none

;****************************************************************************************

include c:\masm32\include\windows.inc
include c:\masm32\include\user32.inc
include c:\masm32\include\kernel32.inc

includelib c:\masm32\lib\user32.lib
includelib c:\masm32\lib\kernel32.lib

;****************************************************************************************

DlgProc proto :DWORD,:DWORD,:DWORD,:DWORD
SHWnd proto :DWORD

;****************************************************************************************

.data
DlgName db "DLG_MAIN",0
strBtnS db "显示 &>>",0
strBtnH db "&<< 隐藏",0

.data?
hInstance HINSTANCE ?
hBtnExpand dd ?
rectFull RECT <?> ;对话框展开后的大小
rectHalf RECT <?> ;对话框收拢后的大小
rectSH RECT <?> ;"显示/隐藏"按钮的位置
bSHWnd BOOL ? ;是否展开窗口的标志

.const
IDC_STATIC equ -1
IDI_MAIN equ 900
IDC_BTN_EXPAND equ 2001

;****************************************************************************************

.code
start:
    invoke GetModuleHandle, NULL
    mov hInstance,eax
    invoke DialogBoxParam,hInstance,addr DlgName,NULL,addr DlgProc,0
    invoke ExitProcess,eax

;对话框窗口过程**************************************************************************

DlgProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM


    .IF uMsg==WM_CLOSE
        invoke EndDialog,hWnd,NULL

    .ELSEIF uMsg==WM_INITDIALOG

        invoke LoadIcon, hInstance, IDI_MAIN
        invoke SendMessage, hWnd, WM_SETICON, ICON_SMALL, eax

        invoke GetWindowRect, hWnd, addr rectFull ;取得窗口大小
        invoke GetDlgItem, hWnd, IDC_BTN_EXPAND ;取得"显示/隐藏"按钮的句柄
        mov hBtnExpand, eax ;句柄 => hBtnExpand
        invoke GetWindowRect, hBtnExpand, addr rectSH ;取得"显示/隐藏"按钮的大小

        push rectFull.left ;为 rectHalf 赋值
        push rectFull.top
        push rectFull.right
        push rectSH.bottom
        pop rectHalf.bottom
        pop rectHalf.right
        pop rectHalf.top
        pop rectHalf.left
        add rectHalf.bottom,12

        mov bSHWnd, FALSE ;窗口第一次显示时呈收拢状态
        invoke SHWnd, hWnd ;调用"展开/收拢窗口"子函数

    .ELSEIF uMsg==WM_COMMAND
        mov eax, wParam
        and eax, 0ffffh
        .IF eax==IDC_BTN_EXPAND
            invoke SHWnd, hWnd
        .ENDIF

    .ELSE
        mov eax,FALSE
        ret
    .ENDIF
    mov eax,TRUE
    ret
DlgProc endp

;展开/收拢窗口子函数*********************************************************************

SHWnd proc hWnd:HWND
    local rect:RECT

    .IF bSHWnd ;展开窗口
        invoke SetWindowText, hBtnExpand, addr strBtnH ;设置按钮文本为"&<< 隐藏"
        mov bSHWnd, FALSE
        push rectFull.left
        pop rect.left
        push rectFull.right
        pop rect.right
        push rectFull.top
        pop rect.top
        push rectFull.bottom
        pop rect.bottom
    .ELSE ;收拢窗口
        invoke SetWindowText, hBtnExpand, addr strBtnS ;设置按钮文本为"显示 &>>"
        mov bSHWnd, TRUE
        push rectHalf.left
        pop rect.left
        push rectHalf.right
        pop rect.right
        push rectHalf.top
        pop rect.top
        push rectHalf.bottom
        pop rect.bottom
    .ENDIF

    mov eax,rect.right ;计算窗口的宽度
    sub eax,rect.left
    mov ebx,eax
    mov eax,rect.bottom ;计算窗口的高度
    sub eax,rect.top
    invoke SetWindowPos, hWnd, NULL, 0, 0, ebx, eax, SWP_NOZORDER or SWP_NOMOVE ;重置窗口大小

    ret
SHWnd endp

end start

分析

invoke GetWindowRect, hWnd, addr rectFull ;取得窗口大小
invoke GetDlgItem, hWnd, IDC_BTN_EXPAND ;取得"显示/隐藏"按钮的句柄
mov hBtnExpand, eax ;句柄 => hBtnExpand
invoke GetWindowRect, hBtnExpand, addr rectSH ;取得"显示/隐藏"按钮的大小

push rectFull.left ;为 rectHalf 赋值
push rectFull.top
push rectFull.right
push rectSH.bottom
pop rectHalf.bottom
pop rectHalf.right
pop rectHalf.top
pop rectHalf.left
add rectHalf.bottom,12

首先取得整个对话框的位置大小,保存在 rectFull 结构里。接着取得“显示 >>”按钮的位置,保存在 rectSH 里。然后计算收拢后的大小 rectHalf。收拢后对话框的下边界的位置由按钮的位置计算出来,两者之间距离 12 象素,这个值是根据实际观察效果确定的。

mov bSHWnd, FALSE ;窗口第一次显示时呈收拢状态
invoke SHWnd, hWnd ;调用"展开/收拢窗口"子函数

hSHWnd 指示当前是处在展开(TRUE)还是收拢状态(FALSE)。对话框第一次显示时我们设定为收拢状态,然后调用函数 SHWnd 来执行展开/收拢动作。函数的实现代码如下:

SHWnd proc hWnd:HWND
    local rect:RECT

    .IF bSHWnd ;展开窗口
        invoke SetWindowText, hBtnExpand, addr strBtnH ;设置按钮文本为"&<< 隐藏"
        mov bSHWnd, FALSE
        push rectFull.left
        pop rect.left
        push rectFull.right
        pop rect.right
        push rectFull.top
        pop rect.top
        push rectFull.bottom
        pop rect.bottom
    .ELSE ;收拢窗口
        invoke SetWindowText, hBtnExpand, addr strBtnS ;设置按钮文本为"显示 &>>"
        mov bSHWnd, TRUE
        push rectHalf.left
        pop rect.left
        push rectHalf.right
        pop rect.right
        push rectHalf.top
        pop rect.top
        push rectHalf.bottom
        pop rect.bottom
    .ENDIF

    mov eax,rect.right ;计算窗口的宽度
    sub eax,rect.left
    mov ebx,eax
    mov eax,rect.bottom ;计算窗口的高度
    sub eax,rect.top
    invoke SetWindowPos, hWnd, NULL, 0, 0, ebx, eax, SWP_NOZORDER or SWP_NOMOVE ;重置窗口大小

    ret
SHWnd endp

判断是展开还是收拢窗口,分别设置不同的按钮文本和窗口大小。当要展开窗口时,则将窗口的完整大小 rectFull 赋值给 rect。当要收拢窗口时,则将窗口的收拢大小 rectHalf 赋值给 rect。最后根据 rect 的值调用 SetWindowPos 函数来设置窗口的大小。

.ELSEIF uMsg==WM_COMMAND
    mov eax, wParam
    and eax, 0ffffh
    .IF eax==IDC_BTN_EXPAND
        invoke SHWnd, hWnd
    .ENDIF

响应按钮消息,调用 SHWnd 函数来展开/收拢窗口。

CopyRight (C) 2001-2002 一块三毛钱

本文地址:http://com.8s8s.com/it/it29615.htm