构件自动清除的内幕
我们已经知道，TComponent在释放自身的时候会自动删除它Owns的所有Component，这是Delphi程序的一个极大特点。否则的话，任何动态生成的对象比如Menu Items都要自己维护和删除，那将是多么痛苦。VCL是如何做到这一点的呢？可以想象到，每个Component内部应该保持一个列表，记录它所拥有的Components，在自身的析构函数中将列表中的所有对象同时删除即可。基本上这个想法是正确的，不过应该考虑到两种可能的情况：（1）构件删除自身的时候，将它所拥有的子构件全部清除，这种情况下子构件是被动的；（2）某个子构件主动地调用了Free或者Destroy，这个时候，父构件应该有办法得到通知，并且维持列表的同步。否则的话，就可能出现某个子构件被析构两次以上的情况，其后果如何大概也可以想到了。
要保持列表的同步，子构件在建立的时候就必须向父构件报告，退出的时候也必须给父构件打个招呼才行。
原理不复杂，现在来看看VCL是如何实现的。TComponent的构造方法叫做Create,带有一个AOwner参数：
constructor TComponent.Create(AOwner: TComponent);
begin
FComponentStyle := [csInheritable];
if AOwner <> nil then AOwner.InsertComponent(Self);
end;
InsertComponent正是我们关心的地方。找找看它的具体实现:
procedure TComponent.InsertComponent(AComponent: TComponent);
begin
AComponent.ValidateContainer(Self);
ValidateRename(AComponent, '', AComponent.FName);
Insert(AComponent);
AComponent.SetReference(True);
if csDesigning in ComponentState then
AComponent.SetDesigning(True);
Notification(AComponent, opInsert);
end;
虽然有些地方还不大明白，不过关键的部分看来是Insert(AComponent)一句。再找到Insert：
procedure TComponent.Insert(AComponent: TComponent);
begin
if FComponents = nil then FComponents := TList.Create;
FComponents.Add(AComponent);
AComponent.FOwner := Self;
end;
我们所猜想的内部列表终于现身，它是一个通用的，可以容纳任何TObject或者Pointer的TList类型。
另外，从上面的代码段也可以看到VCL中比较典型的一种处理方法，那就是对象“只有在需要的时候才建立”，比如上面建立FComponents就是属于这种情况。当然，在每次建立一个构件时都检查一遍FComponent的有效性将会稍稍影响程序的运行速度，但是考虑到程序所占用的内存（Form和Application一般有应该有Components列表，而一般的构件则完全没有必要，如果每个构件都建立一个List的话，那么占用的内存是相当可观的），这种处理方法也有它的道理。
现在再来看看析构时的情况：
destructor TComponent.Destroy;
begin
Destroying;
if FFreeNotifies <> nil then
begin
while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
FreeAndNil(FFreeNotifies);
end;
DestroyComponents;
if FOwner <> nil then FOwner.RemoveComponent(Self);
inherited Destroy;
end;
这里有两个重要的地方：（1）DestroyComponents一句，显然是删除其所拥有的Components；（2）FOwner.RemoveComponents(Self)，看来是把自身从父构件的FComponents列表中移走。
procedure TComponent.DestroyComponents;
var
Instance: TComponent;
begin
while FComponents <> nil do
begin
Instance := FComponents.Last;
if (csFreeNotification in Instance.FComponentState)
or (FComponentState * [csDesigning, csInline] = [csDesigning, csInline]) then
RemoveComponent(Instance)
else
Remove(Instance);
Instance.Destroy;
end;
end;
procedure TComponent.RemoveComponent(AComponent: TComponent);
begin
ValidateRename(AComponent, AComponent.FName, '');
Notification(AComponent, opRemove);
AComponent.SetReference(False);
Remove(AComponent);
end;
RemoveComponent内部又调用了Remove，再看看这个函数：
procedure TComponent.Remove(AComponent: TComponent);
begin
AComponent.FOwner := nil;
FComponents.Remove(AComponent);
if FComponents.Count = 0 then
begin
FComponents.Free;
FComponents := nil;
end;
end;
很简单，是么？通过这一番游历，相信“构件在何种情况下会被自动清除和如何被清除”这个问题应该有了明确的答案，以后写起代码来也应该放心多了。
附记：通过上面的例子，我才体会到Delphi中的导航键是多么方便！不论是自己的单元还是VCL内部单元，用Ctrl+点击和Ctrl+Shift+Up/Down，以及Code Editor中的Back/Forword按钮，三两下就可以定位到任何地方。在Visual C++中就没有这样的方便，不论是用Trace还是用Source Browser，都必须先编译通过才行，即使用Find In Files也不见得快多少。相比起来，在Delphi中跟踪源代码要方便多了。虽说Delphi的启动速度确实慢了点，不过它在其他方面提供的快捷方便还是应该肯定的。
本文地址：http://com.8s8s.com/it/it5808.htm