（1）Body（信件正文） : 字符串
如：JMail.Body = "这里可以是用户填写的表单内容，可以取自From。"
（2）Charset（字符集，缺省为"US-ASCII"） : 字符串
如：JMail.Charset = "US-ASCII"
（3）ContentTransferEncoding : 字符串
指定内容传送时的编码方式，缺省是"Quoted-Printable"
如：JMail.ContentTransferEncoding = "base64"
（4）ContentType（信件的contentype. 缺省是"text/plain"） : 字符串
如果你以HTML格式发送邮件, 改为"text/html"即可。
如：JMail.ContentType = "text/html"
（5）Encoding : 字符串
设置附件编码方式（缺省是"base64）。 可以选择使用的是"base64", "uuencode" or "quoted-printable"
如：JMail.Encoding = "base64"
（6）Log（Jmail创建的日志，前提loging属性设置为true，见下面） : 字符串
如：使用Response.Write( JMail.Log )语句列出日志信息。
（7）Logging（是否使用日志） : 布尔型
如：JMail.Logging = true
（8）Recipients : 字符串
只读属性，返回所有收件人
如：Response.Write( "" + JMail.Recipients + "" );
（9）ReplyTo（指定别的回信地址） : 字符串
如：JMail.ReplyTo = "[email protected]"
（10）Sender（ 发件人的邮件地址） : 字符串
如：JMail.Sender = "[email protected]"
（11）SenderName（发件人的姓名） : 字符串
如：JMail.SenderName = "一克"
（12）ServerAddress（邮件服务器的地址） : 字符串
你可以指定多个服务器，用分号点开。可以指定端口号。
如果serverAddress保持空白，JMail会尝试远程邮件服务器，然后直接发送到服务器上去。
如：JMail.ServerAddress = "mail.21cn.net.cn"
（13）Subject（设定邮件的标题，可以取自From。）：字符串
如：JMail.Subject = "客户反馈表单"
（14）添加文件附件到邮件
如：JMail.AddAttachment( "c:\anyfile.zip" )
（15）AddCustomAttachment( FileName, Data )
添加自定义附件.
如：JMail.AddCustomAttachment( "anyfile.txt", "Contents of file" );
（16）AddHeader( Header, Value )
添加用户定义的信件标头。
如：JMail.AddHeader( "Originating-IP","192.158.1.10" );
（17）AddRecipient（收件人）：字符串
如：JMail.AddRecipient( "[email protected]" );
（18）AddRecipientBCC( Email )，密件收件人：
如：JMail.AddRecipientBCC( "[email protected]" );
（19）AddRecipientCC( Email ) ，抄送收件人：
如：JMail.AddRecipientCC( "" )
（20）AddURLAttachment( URL, 文档名)
下载并添加一个来自url的附件. 第二个参数"文档名", 用来指定信件收到后的文件名。
如：JMail.AddURLAttachment( "http://www.chinabs.net/jmail.zip", "jmail" )
（21）AppendBodyFromFile( 文件名) ，将文件作为信件正文：
如：JMail.AppendBodyFromFile( "c:\anyfile.txt" )
(22)AppendText( Text )
追加信件的正文内容，比如增加问候语或者其它信息。
如：JMail.AppendText( "欢迎访问本站！" )
（23）Close() ，强制JMail关闭缓冲的与邮件服务器的连接：
如：JMail.Close()
（24）Execute() ，执行邮件的发送
如：JMail.Execute()
下面是一个忘记密码时的程序代码：
程序代码：
path=Server.MapPath("\images\logo.gif")
Set JMail=Server.CreateObject("JMail.SMTPMail")
JMail.ContentType="text/html"
JMail.Encoding = "base64"
JMail.Charset="gb2312"
JMail.ServerAddress = "mail.chinabs.net"
JMail.Sender = [email protected]
JMail.Subject = "chinabs.net发给您的密码！"
JMail.AddRecipient(email)
JMail.Body =str
JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")
JMail.AddAttachment(path)
JMail.Execute
JMail.Close
Set JMail = Nothing
前一段时间有发过一个简单的JMAIL邮件发邮件的代码，今天就把这个代码做一个具体的注解，并增加了另外两个格式的代码，并举几个简单的例子：
首先是jmail.smtpmail的核心代码：
<%
Set jmail = Server.CreateObject("JMAIL.SMTPMail") '创建一个JMAIL对象
jmail.silent = true 'JMAIL不会抛出例外错误，返回的值为FALSE跟TRUE
jmail.logging = true '启用使用日志
jmail.Charset = "GB2312" '邮件文字的代码为简体中文
jmail.ContentType = "text/html" '邮件的格式为HTML的
jmail.ServerAddress = "Server Address" '发送邮件的服务器
jmail.AddRecipient Email '邮件的收件人
jmail.SenderName = "SenderName" '邮件发送者的姓名
jmail.Sender = "Email Address" '邮件发送者的邮件地址
jmail.Priority = 1 '邮件的紧急程序，1 为最快，5 为最慢， 3 为默认值
jmail.Subject = "Mail Subject" '邮件的标题
jmail.Body = "Mail Body" '邮件的内容
jmail.AddRecipientBCC Email '密件收件人的地址
jmail.AddRecipientCC Email '邮件抄送者的地址
jmail.Execute() '执行邮件发送
jmail.Close '关闭邮件对象
%>
w3 Jmail4.3组件重新设计了其内部结构——使用Message对象代替原来的单一对象Jmail.smtpmail发送邮件，有些方法需要身份验证的(如163、yahoo等)，可以用下面的方法解决：
<%
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象
jmail.silent = true '屏蔽例外错误，返回FALSE跟TRUE两值j
mail.logging = true '启用邮件日志
jmail.Charset = "GB2312" '邮件的文字编码为国标
jmail.ContentType = "text/html" '邮件的格式为HTML格式
jmail.AddRecipient Email '邮件收件人的地址
jmail.From = "Email From for Sender" '发件人的E-MAIL地址
jmail.MailServerUserName = "UserName of Email" '登录邮件服务器所需的用户名
jmail.MailServerPassword = "Password of Email" '登录邮件服务器所需的密码
jmail.Subject = "Mail Subject" '邮件的标题
jmail.Body = "Mail Body" '邮件的内容
jmail.Prority = 1 '邮件的紧急程序，1 为最快，5 为最慢， 3 为默认值
jmail.Send("Server Address") '执行邮件发送（通过邮件服务器地址）
jmail.Close() '关闭对象
%>
再讲一下微软自带的CDONTS组件的发信的方法：
<%
Set cdomail = Server.CreateObject("CDONTS.NewMail") '建立邮件对象
cdomail.Subject = "Mail Subject" '邮件标题
cdomail.From = "Sender's Mail" '发件人的地址
cdomail.To = "Email will from" '收件人的地址
cdomail.Body = "Mail Body" '邮件的内容
cdomail.Send '执行发送
%>
这种方法发送邮件是最简单的，同时也带来一定的问题，就是很少有服务器会开这项服务！
我们写程序，一般情况下都是说要代码模块化，这样方便维护，同时也方便移植。因此，我在这里将这个发邮件的写成一个子程，在调用的时候可以直接调用（当然，如果你高兴写成函数的话也是可以的，这个主要是看个人兴趣）：
<%
'参数说明
'Subject : 邮件标题
'MailAddress : 发件服务器的地址,如smtp.163.com
'Email : 收件人邮件地址
'Sender : 发件人姓名
'Content : 邮件内容
'Fromer : 发件人的邮件地址
Sub SendAction(subject, mailaddress, email, sender, content, fromer)
Set jmail = Server.CreateObject("JMAIL.SMTPMail") '创建一个JMAIL对象
jmail.silent = true 'JMAIL不会抛出例外错误，返回的值为FALSE跟TRUE
jmail.logging = true '启用使用日志
jmail.Charset = "GB2312" '邮件文字的代码为简体中文
jmail.ContentType = "text/html" '邮件的格式为HTML的
jmail.ServerAddress = mailaddress '发送邮件的服务器
jmail.AddRecipient Email '邮件的收件人
jmail.SenderName = sender '邮件发送者的姓名
jmail.Sender = fromer '邮件发送者的邮件地址
jmail.Priority = 1 '邮件的紧急程序，1 为最快，5 为最慢， 3 为默认值
jmail.Subject = subject '邮件的标题
jmail.Body = content '邮件的内容
'由于没有用到密抄跟抄送，这里屏蔽掉这两句，如果您有需要的话，可以在这里恢复
'jmail.AddRecipientBCC Email '密件收件人的地址
'jmail.AddRecipientCC Email '邮件抄送者的地址
jmail.Execute() '执行邮件发送
jmail.Close '关闭邮件对象
End Sub
'调用此Sub的例子
Dim strSubject,strEmail,strMailAdress,strSender,strContent,strFromer
strSubject = "这是一封用JMAIL发送的测试邮件"
strContent = "JMail组件发送测试成功！"
strEmail = "[email protected]"
strFromer = "[email protected]"
strMailAddress = "mail.ubbcn.com"
Call SendAction (strSubject,strMailaddress,strEmail,strSender,strContent,strFromer)
%>
本文地址：http://com.8s8s.com/it/it8261.htm